diff --git a/.gitignore b/.gitignore
index ea8c4bf..d787b70 100644
--- a/.gitignore
+++ b/.gitignore
@@ -1 +1,2 @@
 /target
+/result
diff --git a/flake.lock b/flake.lock
new file mode 100644
index 0000000..926d5b3
--- /dev/null
+++ b/flake.lock
@@ -0,0 +1,27 @@
+{
+  "nodes": {
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1774106199,
+        "narHash": "sha256-US5Tda2sKmjrg2lNHQL3jRQ6p96cgfWh3J1QBliQ8Ws=",
+        "owner": "NixOS",
+        "repo": "nixpkgs",
+        "rev": "6c9a78c09ff4d6c21d0319114873508a6ec01655",
+        "type": "github"
+      },
+      "original": {
+        "owner": "NixOS",
+        "ref": "nixos-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}
diff --git a/flake.nix b/flake.nix
new file mode 100644
index 0000000..6b5c877
--- /dev/null
+++ b/flake.nix
@@ -0,0 +1,82 @@
+{
+    description = "Slimes Benchmark Server";
+
+    inputs = {
+        nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    };
+
+    outputs =
+        { self, nixpkgs }:
+        let
+            supportedSystems = [
+                "x86_64-linux"
+            ];
+            forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
+        in
+        {
+            packages = forAllSystems (
+                system:
+                let
+                    pkgs = import nixpkgs { inherit system; };
+                in
+                {
+                    default = pkgs.rustPlatform.buildRustPackage {
+                        pname = "slimes-server";
+                        version = "0.1.0";
+
+                        src = ./server;
+
+                        cargoLock.lockFile = ./server/Cargo.lock;
+
+                        nativeBuildInputs = [ pkgs.pkg-config ];
+                        buildInputs = [ pkgs.sqlite ];
+
+                        # doCheck = false;
+                    };
+                }
+            );
+
+            nixosModules.default =
+                {
+                    config,
+                    lib,
+                    pkgs,
+                    ...
+                }:
+                let
+                    cfg = config.services.slimes-server;
+                in
+                {
+                    options.services.slimes-server = {
+                        enable = lib.mkEnableOption "Slimes Server";
+                        port = lib.mkOption {
+                            type = lib.types.port;
+                            default = 9003;
+                        };
+                        databasePath = lib.mkOption {
+                            type = lib.types.str;
+                            default = "/var/lib/slimes-server/slimes.db";
+                        };
+                    };
+
+                    config = lib.mkIf cfg.enable {
+                        systemd.services.slimes-server = {
+                            description = "Slimes Benchmark Server";
+                            after = [ "network.target" ];
+                            wantedBy = [ "multi-user.target" ];
+                            serviceConfig = {
+                                ExecStart = "${
+                                    self.packages.${pkgs.system}.default
+                                }/bin/slimes-server --database-url ${cfg.databasePath} --port ${toString cfg.port}";
+                                Restart = "on-failure";
+                                StateDirectory = "slimes-server";
+                                DynamicUser = true;
+                                ProtectSystem = "strict";
+                                ProtectHome = true;
+                                NoNewPrivileges = true;
+                            };
+                        };
+                    };
+                };
+        };
+}
diff --git a/server/Cargo.toml b/server/Cargo.toml
index 850f059..a9f315c 100644
--- a/server/Cargo.toml
+++ b/server/Cargo.toml
@@ -1,5 +1,5 @@
 [package]
-name = "server"
+name = "slimes-server"
 version = "0.1.0"
 edition = "2024"